% V20210224 - 11.14 Spinner Customization [2]

INCLUDE "GW.bas"
 
% Create page.
p = GW_NEW_PAGE()

% Prepare title bar string.
ti$ = GW_ADD_BAR_TITLE$("Spinner Custo Example")

% Add title bar with buttons to page.
GW_ADD_TITLEBAR(p, ti$)

% Create icons from online resources.
red  = GW_ADD_ICON(p, "http://mougino.free.fr/tmp/redloader.gif", 32, 32)
four = GW_ADD_ICON(p, "http://mougino.free.fr/tmp/4colloader.gif", 32, 32)

% Add 2 custom spinners.
GW_USE_THEME_CUSTO_ONCE("icon="+gw_id$(four))
spin1 = GW_ADD_SPINNER(p, "")

GW_USE_THEME_CUSTO_ONCE("icon="+GW_ID$(red))
spin2 = GW_ADD_SPINNER(p, "")

% Add text.
btc$ = "US$ 1,000"
GW_ADD_TEXT(p, "Your Bitcoin wallet is currently worth:")
GW_USE_THEME_CUSTO_ONCE("align=center")
btc = GW_ADD_TITLE(p, btc$)
GW_ADD_TEXT(p, "Swipe down to refresh results.")

% Add listener.
GW_ADD_LISTENER(p, 0, "swipedown", "refresh")

% Show the page.
GW_RENDER(p)

% Quit on BACK key.
DO
  r$ = GW_WAIT_ACTION$()

  IF r$ = "refresh"
    IF spin <> spin1 THEN spin = spin1 ELSE spin = spin2
    GW_SHOW_SPINNER(spin)
    PAUSE 1800
    GW_CLOSE_PAGE(p)
    btc$ += ",000"
    GW_RENDER(p)
    GW_MODIFY(btc, "text", btc$)
  ENDIF

UNTIL r$ = "BACK"

END "End of Spinner Custo Example"